Main Page

Welcome do DHwiki Wikibase. This mediaWiki installation, hosted on Wikibase Cloud, includes a Wikibase instance, and is maintained since September 2024 by the DARIAH-EU WG DHwiki, in the framework of the DARIAH ERIC. Here is the public announce of the WG creation.

You find dates and agendas of our group meetings here: Group_meetings.

At the moment, we are using this Wikibase for a LOD version of our group bibliography (a Zotero collection available here (see list of contributors)), and to list information about group members.

What's in DHwiki Wikibase?

Bibliographical items

#title: All bibliographical items
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>

select ?item ?typeLabel ?date ?itemLabel ?langLabel (iri(concat(str(wd:),?wd)) as ?wikidata)
       
where { 
  ?item dhdp:P5 dhwb:Q2; dhdp:P8 ?type; dhdp:P26 ?date; dhdp:P11 ?lang.
  optional {?item dhdp:P1 ?wd.}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by desc(year(?date))

Try it!

Persons

Authors

At the moment, we have persons authoring publications from the above bibliography (some we could find easily on Wikidata)

#title: Persons we have aligned to Wikidata
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>

select ?item ?itemLabel (iri(concat(str(wd:),?wd)) as ?wikidata)
       
where { 
  ?item dhdp:P5 dhwb:Q5; rdfs:label ?itemLabel. filter(lang(?itemLabel)="en")
  optional {?item dhdp:P1 ?wd.}
} order by ?itemLabel

Try it!

Group members

Persons on this Wikibase that according to Wikidata are members of this group:

#title: Persons we have on this Wikibase and that are members of "DARIAH WG DHwiki" according to Wikidata
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>

select ?item ?itemLabel ?wikidata ?orcid ?other_institutions ?image
       
where { 
  ?item dhdp:P5 dhwb:Q5; dhdp:P1 ?wd; rdfs:label ?itemLabel. 
  filter(lang(?itemLabel)="en") bind(iri(concat(str(wd:),?wd)) as ?wikidata)
  SERVICE <https://query.wikidata.org/sparql> {
           select ?wikidata ?orcid (group_concat(distinct ?other_groupLabel;SEPARATOR=", ") as ?other_institutions) ?image
           where { ?wikidata wdt:P463 wd:Q130741564. # member of DARIAH WG DHwiki
                  optional {?wikidata wdtn:P496 ?orcid.}
                  optional {?wikidata wdt:P463|wdt:P108 ?other_group. # member of / employed by
                            filter (?other_group != wd:Q130741564)
                            ?other_group rdfs:label ?other_groupLabel.
                            filter(lang(?other_groupLabel)="en")}
                  optional {?wikidata wdt:P18 ?image.}
           } group by ?wikidata ?orcid ?other_institutions ?image
    } 
} order by ?itemLabel

Try it!

Classes and instances on this Wikibase

#title: Classes and # of instances on this Wikibase
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>

select ?class ?classLabel (count(?wikibase_item) as ?how_many_instances) 
       
where { 
  ?class dhdp:P5 dhwb:Q1.
  ?wikibase_item dhdp:P5 ?class.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?class ?classLabel ?how_many_instances order by desc(?how_many_instances)

Try it!