Main Page

Welcome do DHwiki Wikibase. This mediaWiki installation, hosted on Wikibase Cloud, includes a Wikibase instance, and is maintained since September 2024 by the DARIAH-EU WG DHwiki, in the framework of the DARIAH ERIC. Here is the public announce of the WG creation.

You find dates and agendas of our group meetings here: Group_meetings.

At the moment, we are using this Wikibase for a LOD version of our group bibliography (a Zotero collection available here (see list of contributors)), and to list information about group members.

What's in DHwiki Wikibase?

Bibliographical items

If you add items to our Zotero group, please follow our Zotero guidelines.

#title: All bibliographical items
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>

select ?item ?typeLabel ?date ?itemLabel ?langLabel (iri(concat(str(wd:),?wd)) as ?wikidata)
       
where { 
  ?item dhdp:P5 dhwb:Q2; dhdp:P8 ?type; dhdp:P26 ?date; dhdp:P11 ?lang.
  optional {?item dhdp:P1 ?wd.}
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by desc(year(?date))

Try it!

Persons

Authors

At the moment, we have persons authoring publications from the above bibliography (some we could find easily on Wikidata)

#title: Persons we have aligned to Wikidata
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>

select ?item ?itemLabel (iri(concat(str(wd:),?wd)) as ?wikidata)
       
where { 
  ?item dhdp:P5 dhwb:Q5; rdfs:label ?itemLabel. filter(lang(?itemLabel)="en")
  optional {?item dhdp:P1 ?wd.}
} order by ?itemLabel

Try it!

Group members

Persons on this Wikibase that according to Wikidata are members of this group:

#title: Persons that are members of "DARIAH WG DHwiki" according to Wikidata
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>

select ?dhwiki_item ?wikidata_label ?wikidata ?orcid ?other_institutions ?image
       
where { 
  SERVICE <https://query.wikidata.org/sparql> {
           select ?wikidata ?wikidata_label ?orcid (group_concat(distinct ?other_groupLabel;SEPARATOR=", ") as ?other_institutions) ?image
           where { ?wikidata rdfs:label ?wikidata_label; wdt:P463 wd:Q130741564. # member of DARIAH WG DHwiki
                  filter(lang(?wikidata_label)="en")
                  optional {?wikidata wdtn:P496 ?orcid.}
                  optional {?wikidata wdt:P463|wdt:P108 ?other_group. # member of / employed by
                            filter (?other_group != wd:Q130741564)
                            ?other_group rdfs:label ?other_groupLabel.
                            filter(lang(?other_groupLabel)="en")}
                  optional {?wikidata wdt:P18 ?image.}
           } group by ?wikidata ?wikidata_label ?orcid ?other_institutions ?image
    }
 optional { ?dhwiki_item dhdp:P5 dhwb:Q5; dhdp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
} order by lcase(?wikidata_label)

Try it!

Wikibase instances described on Wikibase World and on DHwiki Wikibase

#title: Wikibase instances described on Wikibase World and on DHwiki Wikibase
PREFIX wwwb: <https://wikibase.world/entity/>
PREFIX wwdp: <https://wikibase.world/prop/direct/>

select ?wikibase ?wikibase_name ?dhwiki_page
       
where { 
  SERVICE <https://wikibase.world/query/sparql> {
  ?wikibase wwdp:P3 wwwb:Q10; rdfs:label ?wikibase_name. filter(lang(?wikibase_name)="en")
  ?wikibase wwdp:P66 ?dhwiki_page. filter(regex(str(?dhwiki_page), "dhwiki.wikibase.cloud"))
  }
}

Try it!

Classes and instances on this Wikibase

#title: Classes and # of instances on this Wikibase
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>

select ?class ?classLabel (count(?wikibase_item) as ?how_many_instances) 
       
where { 
  ?class dhdp:P5 dhwb:Q1.
  ?wikibase_item dhdp:P5 ?class.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?class ?classLabel ?how_many_instances order by desc(?how_many_instances)

Try it!