Main Page
From DHWiki
DHwiki
Welcome do DHwiki Wikibase. This mediaWiki installation, hosted on Wikibase Cloud, includes a Wikibase instance, and is maintained since September 2024 by the DARIAH-EU WG DHwiki, in the framework of the DARIAH ERIC.
Introduction reads and links
- The announcement of the WG creation from November 2024.
- A short set of slides about our group (May 2025) here: https://doi.org/10.5281/zenodo.16041468
- A short set of slides about our first year of activity (May 2026) here: https://doi.org/10.5281/zenodo.20397226
- List of DHwiki outreach activities (talks, etc.)
- DHwiki item on Wikidata: https://www.wikidata.org/wiki/Q130741564
- DHwiki Commons category: https://commons.wikimedia.org/wiki/Category:DARIAH-EU_DHwiki_Working_Group
Group meetings
- You find dates and agendas of our online group meetings here: Group meetings.
- Face-to-face meeting Rome 2026
DHwiki documentation pages
We are currently working on the documentation pages listed here. Any feedback or contribution is warmly welcome.
Quick Access to the DHwiki documentation pages:
- Overview page, with credits to contributors
- Introduction
- Structure and features of Wikibase for DH
- Wikibase and Wikidata, differences and round-tripping
- Wikidata and Wikibase as a hub for identifiers
- Examples of existing Wikibase instances in the field of DH and GLAM
- Pages in Category:Wikibase instances
- Requirements from a DH perspective
- Wikibase Lexical Data
- Resource directory and Bibliography
- our group library at Zotero (see list of contributors))
- our bibliography in this Wikibase (see below)
DHwiki on Zenodo and on Zotero
The group has set up a Zenodo community, where you find our papers and presentation slides: https://zenodo.org/communities/dariah_dhwiki/
The group maintains a Zotero group, from where bibliographical items are imported into this Wikibase: https://www.zotero.org/groups/5639268/dariah_dhwiki/library
We also are having experiments with a set of Jupyter notebooks using data from this Wikibase instance as showcase.
What's in DHwiki Wikibase?
Group meetings
- See Group meetings.
DHwiki outreach and event participation
- See DHwiki on tour.
Bibliographical items
If you add items to our Zotero group, please follow our Zotero guidelines.
#title: All bibliographical items
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>
select ?item ?typeLabel ?date ?itemLabel ?langLabel (iri(concat(str(wd:),?wd)) as ?wikidata)
where {
?item dhdp:P5 dhwb:Q2; dhdp:P8 ?type; dhdp:P26 ?date; dhdp:P11 ?lang.
optional {?item dhdp:P1 ?wd.}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by desc(year(?date))
Bibliographical items domains
#title: All bibliographical items indexed with domain labels, sorted by domain
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>
select ?domainLabel ?item ?typeLabel ?date ?itemLabel ?langLabel (iri(concat("https://www.zotero.org/groups/5639268/dariah_wg_dhwiki/items/",?zot,"/item-details")) as ?zotero) (iri(concat(str(wd:),?wd)) as ?wikidata)
where {
?item dhdp:P5 dhwb:Q2; dhdp:P8 ?type; dhdp:P41 ?domain; dhdp:P26 ?date; dhdp:P11 ?lang; dhdp:P6 ?zot.
optional {?item dhdp:P1 ?wd.}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?domainLabel desc(year(?date))
Persons
Authors
At the moment, we have persons authoring publications from the above bibliography (some we could find easily on Wikidata)
#title: Persons we have aligned to Wikidata
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>
select ?item ?itemLabel (iri(concat(str(wd:),?wd)) as ?wikidata)
where {
?item dhdp:P5 dhwb:Q5; rdfs:label ?itemLabel. filter(lang(?itemLabel)="en")
optional {?item dhdp:P1 ?wd.}
} order by ?itemLabel
Group members
Persons on this Wikibase that according to Wikidata are members of this group:
#title: Persons that are members of "DARIAH WG DHwiki" according to Wikidata
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>
select ?dhwiki_item ?wikidata_label ?wikidata ?orcid ?other_institutions ?image
where {
SERVICE <https://query.wikidata.org/sparql> {
select ?wikidata ?wikidata_label ?orcid (group_concat(distinct ?other_groupLabel;SEPARATOR=", ") as ?other_institutions) ?image
where { ?wikidata rdfs:label ?wikidata_label; wdt:P463 wd:Q130741564. # member of DARIAH WG DHwiki
filter(lang(?wikidata_label)="en")
optional {?wikidata wdtn:P496 ?orcid.}
optional {?wikidata wdt:P463|wdt:P108 ?other_group. # member of / employed by
filter (?other_group != wd:Q130741564)
?other_group rdfs:label ?other_groupLabel.
filter(lang(?other_groupLabel)="en")}
optional {?wikidata wdt:P18 ?image.}
} group by ?wikidata ?wikidata_label ?orcid ?other_institutions ?image
}
optional { ?dhwiki_item dhdp:P5 dhwb:Q5; dhdp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
} order by lcase(?wikidata_label)
Group members image gallery
#title: Persons that are members of "DARIAH WG DHwiki" according to Wikidata
#defaultView:ImageGrid
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>
select ?dhwiki_item ?wikidata_label ?wikidata ?desc ?orcid ?other_institutions ?image
where {
SERVICE <https://query.wikidata.org/sparql> {
select ?wikidata ?wikidata_label ?desc ?orcid (group_concat(distinct ?other_groupLabel;SEPARATOR=", ") as ?other_institutions) ?image
where { ?wikidata rdfs:label ?wikidata_label; wdt:P463 wd:Q130741564. # member of DARIAH WG DHwiki
filter(lang(?wikidata_label)="en")
optional {?wikidata schema:description ?desc. filter(lang(?desc)="en")}
optional {?wikidata wdtn:P496 ?orcid.}
optional {?wikidata wdt:P463|wdt:P108 ?other_group. # member of / employed by
filter (?other_group != wd:Q130741564)
?other_group rdfs:label ?other_groupLabel.
filter(lang(?other_groupLabel)="en")}
optional {?wikidata wdt:P18 ?image.}
} group by ?wikidata ?wikidata_label ?desc ?orcid ?other_institutions ?image
}
optional { ?dhwiki_item dhdp:P5 dhwb:Q5; dhdp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
} order by lcase(?wikidata_label)
Group members' fields of expertise
#title: DHwiki group members and their fields of expertise
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>
select ?dhwiki_item ?wikidata_label ?wikidata ?orcid ?other_institutions (group_concat(?expertise; SEPARATOR=", ") as ?fields_of_expertise)
where {
SERVICE <https://query.wikidata.org/sparql> {
select ?wikidata ?wikidata_label ?orcid (group_concat(distinct ?other_groupLabel;SEPARATOR=", ") as ?other_institutions)
where { ?wikidata rdfs:label ?wikidata_label; wdt:P463 wd:Q130741564. # member of DARIAH WG DHwiki
filter(lang(?wikidata_label)="en")
optional {?wikidata wdtn:P496 ?orcid.}
optional {?wikidata wdt:P463|wdt:P108 ?other_group. # member of / employed by
filter (?other_group != wd:Q130741564)
?other_group rdfs:label ?other_groupLabel.
filter(lang(?other_groupLabel)="en")}
} group by ?wikidata ?wikidata_label ?orcid ?other_institutions
}
optional { ?dhwiki_item dhdp:P5 dhwb:Q5; dhdp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)
optional { ?dhwiki_item dhdp:P42 [rdfs:label ?expertise]. filter(lang(?expertise)="en")}}
} group by ?dhwiki_item ?wikidata_label ?wikidata ?orcid ?other_institutions ?fields_of_expertise
order by lcase(?wikidata_label)
A query for fields of expertise and group members skilled in these:
#title: DHwiki fields of expertise (instances of "field of expertise": P5 - Q120)
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>
select ?field ?field_label (group_concat(?member_name; SEPARATOR=", ") as ?group_members)
where {
?field dhdp:P5 dhwb:Q120; rdfs:label ?field_label. filter(lang(?field_label)="en")
optional {?member dhdp:P42 ?field; rdfs:label ?member_name. filter(lang(?member_name)="en")}
} group by ?field ?field_label ?group_members
Wikibase instances described on Wikibase World and on DHwiki Wikibase
#title: Wikibase instances described on Wikibase World and on DHwiki Wikibase
PREFIX wwwb: <https://wikibase.world/entity/>
PREFIX wwdp: <https://wikibase.world/prop/direct/>
select ?wikibase ?wikibase_name ?dhwiki_page
where {
SERVICE <https://wikibase.world/query/sparql> {
?wikibase wwdp:P3 wwwb:Q10; rdfs:label ?wikibase_name. filter(lang(?wikibase_name)="en")
?wikibase wwdp:P66 ?dhwiki_page. filter(regex(str(?dhwiki_page), "dhwiki.wikibase.cloud"))
}
}
Classes and instances on this Wikibase
#title: Classes and # of instances on this Wikibase
PREFIX dhwb: <https://dhwiki.wikibase.cloud/entity/>
PREFIX dhdp: <https://dhwiki.wikibase.cloud/prop/direct/>
select ?class ?classLabel (count(?wikibase_item) as ?how_many_instances)
where {
?class dhdp:P5 dhwb:Q1.
?wikibase_item dhdp:P5 ?class.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} group by ?class ?classLabel ?how_many_instances order by desc(?how_many_instances)
